excel中count if函數的使用方法
excel中count if函數的使用方法
Excel IF函數即count if 函數，運用它可以對一系列繁雜的數據進行篩選，得到自己想要的數據結果。今天，學習啦小編就教大家在Excel中count if 函數的使用方法。
Excel中COUNTIF函數使用方法一
(1) 求真空單元格個數:=COUNTIF(數據區,"=")
(2) 非真空單元格個數: =COUNTIF(數據區,"<>") 相當于counta()函數
(3) 文本型單元格個數: =COUNTIF(數據區,"*") 假空單元格也是文本型單元格
(4) 區域內所有單元格個數: =COUNTIF(數據區,"<>"""),如果數據區內有",該公式不成立.
(5) 邏輯值為TRUE的單元格數量 =COUNTIF(數據區,TRUE)
Excel中COUNTIF函數使用方法二
(1) 大于50=COUNTIF(數據區,">50")
(2) 等于50=COUNTIF(數據區,50)
(3) 小于50 =COUNTIF(數據區,"<50")
(4) 大于或等于50 =COUNTIF(數據區,">=50")
(5) 小于或等于50 =COUNTIF(數據區,"<=50")
(6) 大于E5單元格的值 =COUNTIF(數據區,">"&$E)
(7) 等于E5單元格的值 =COUNTIF(數據區,$E)
(8) 小于E5單元格的值 =COUNTIF(數據區,"<"&$E)
(9) 大于或等于E5單元格的值 =COUNTIF(數據區,">="&$E)
(10) 小于或等于E5單元格的值 =COUNTIF(數據區,"<="&$E)
Excel中COUNTIF函數使用方法三
(1) 兩個字符 =COUNTIF(數據區,"??")
(2) 兩個字符并且第2個是B=COUNTIF(數據區,"?B")
(3) 包含B =COUNTIF(數據區,"*B*")
(4) 第2個字符是B =COUNTIF(數據區,"?B*")
(5) 等于“你好”=COUNTIF(數據區,"你好")
(6) 包含D3單元格的內容 =COUNTIF(數據區,"*"&D3&"*")
(7) 第2字是D3單元格的內容 =COUNTIF(數據區,"?"&D3&"*")
注：countif()函數對英文字母不區分大小寫，通配符只對文本有效
Excel中COUNTIF函數使用方法四:兩個條件求個數
(1)>10并且<=15 =SUM(COUNTIF(數據區,">"&{10,15})*{1,-1})
(2)>=10并且<15 =SUM(COUNTIF(數據區,">="&{10,15})*{1,-1})
(3)>=10并且<=15 =SUM(COUNTIF(數據區,{">=10",">15"})*{1,-1})
(4)>10并且<15 =SUM(COUNTIF(數據區,{">10",">=15"})*{1,-1})或者=SUM(COUNTIF(數據區,{">10",">=15"})-樣本數
注：一般多條件計數使用SUMPRODUCT函數，以上方法較少使用，僅供參考。
補充：
三個區域計數： 三個區域中>=60 =SUM(COUNTIF(INDIRECT({"a46:a48","b48:b50","c47:c48"}),">=60"))
補充：(集合運算法)
統計范圍，比如5<= x <=7
可以分解為(x>=5)-(x>7)
寫為函數：
=countif(range,">=5")-countif(range,">7")
猜你喜歡：